Tables: Créer un champ Hyperlink à partir du code	Author(s) Dev Ashish

Créer un champ Hyperlink à partir du code.

(Q)    Je suis incapable de créer un champ Hyperlink dans une table, depuis le code. Quelles sont les étapes pour y parvenir?

(A)    Pour créer un champ Hyperlink, vous devez lever l'attribut approprié de dbHyperlinkField. 

    Voici un exemple.

'****************** Code Start *******************
Function fTableWithHyperlink(stTablename As String) As Boolean
   On Local Error GoTo fTableWithHyperlink_Err
Dim Msg As String ' pour traitement d'erreur
Dim db As Database
Dim tdf As TableDef
Dim fld As Field
    Set db = CurrentDb
    Set tdf = db.CreateTableDef(stTablename)
    Set fld = tdf.CreateField("HyperlinkTest", dbMemo)
    fld.Attributes = dbHyperlinkField
    tdf.Fields.Append fld
    tdf.Fields.Refresh
    db.TableDefs.Append tdf
    db.TableDefs.Refresh
    Set fld = Nothing
    Set tdf = Nothing
    Set db = Nothing
   
    fTableWithHyperlink = True

fTableWithHyperlink_End:
   Exit Function

fTableWithHyperlink_Err:
   fTableWithHyperlink = False
   Msg = "Error Information..." & vbCrLf & vbCrLf
   Msg = Msg & "Function: fTableWithHyperlink" & vbCrLf
   Msg = Msg & "Description: " & Err.Description & vbCrLf
   Msg = Msg & "Error #: " & Format$(Err.Number) & vbCrLf
   MsgBox Msg, vbInformation, "fTableWithHyperlink"
   Resume fTableWithHyperlink_End
End Function
'****************** Code End *******************