General: Access 2000: Cacher l'onglet Replace du dialogue Find/Replace	Author(s) Dev Ashish

--- Soumis par Dev Ashish---

Access 2000: Cacher l'onglet Replace du dialogue Find/Replace

Les dialogues Find et Replace jusqu'alors séparés dans les versions antérieures d'Access et invoqués à partir de la combinaison de clés  Control-F et Control-H respectivement (ou en appelant RunCommand) sont maintenant réunis sous Access dans un formulaire à onglets.

Quelques développeurs ont exprimés leur réticence, par courrier électronique ou dans des groupes de discussion, quant à présenter à leur utilisateur autant de fonctionnalité, principalement de par le  Replace, alors que seule la recherche est souhaitée.

Access 2000 ne présente pas de possibilité intégrée pour manipuler la présentation de ce formulaire, mais si vous marquez le formulaire ou la table impliquée comme étant en lecture seule ( Read-Only ) avant d'ouvrir le dialogue à partir du code, Access cache automatiquement l'onglet  Replace, car l'utilisateur ne peut pas faire de modification sur un objet qui n'est accessible qu'en lecture.

Les procédures suivantes illustrent le processus de marquage d'un formulaire ou d'une table en "lecture seule", puis, lancent le dialogue  Find/Replace.

' ***** Code Start *********
Sub sFindReplaceInForm(strFormName As String)
On Error GoTo ErrHandler

Const ERR_GENERIC = vbObjectError + 6666

    ' Ouvrir le formulaire
    DoCmd.OpenForm strFormName, _
                                        acNormal

    ' Porter le formulaire en Lecture seule
    ' Ce mode prévient l'affichage de l'onglet Replace
    ' dans le dialogue
    With Forms(strFormName)
        .AllowAdditions = False
        .AllowDeletions = False
        .AllowEdits = False
    End With

    ' choisir le formulaire de par l'Interface Utilisateur
    DoCmd.SelectObject acForm, _
                                    strFormName, _
                                    False

    ' Affichage du dialogue  Find/Replace 
    DoCmd.RunCommand acCmdFind

ExitHere:
    Exit Sub
ErrHandler:
    Resume ExitHere
End Sub

Sub sFindReplaceInTable(strTableName As String)
On Error GoTo ErrHandler

Const ERR_GENERIC = vbObjectError + 6666

    ' Ouvrir la table.
    ' Le mode lecture seule prévient l'affichage
    ' de l'onglet Replace dans le dialogue
    DoCmd.OpenTable strTableName, _
                                        acViewNormal, _
                                        acReadOnly

    ' choisir la table de par l'interface utilisateur
    DoCmd.SelectObject acTable, _
                                    strTableName, _
                                    False

    ' Affichage du dialogue  Find/Replace
    DoCmd.RunCommand acCmdFind

ExitHere:
    Exit Sub
ErrHandler:
    Resume ExitHere
End Sub
' ******** Code End *********